100 REM * MEMLO-VERSCHIEBUNG
110 REM * ERZEUGT AUTORUN.SYS
120 REM
130 REM * P. FINZEL
140 ? "Untere Speichergrenze bei:”;:INPUT MEMLO
150 MH=INT(MEMLO/256)
160 ML=MEMLO-MH*256
170 DIM D$(80):OPEN #1,8,0,"D:AUTORUN.SYS"
180 ? "AUTORUN.SYS wird generiert...":? :FLAG=0
190 READ D$:READ P:IF D$="*" THEN 290
200 S=0:? "*";
210 FOR I=1 TO LEN(D$) STEP 2
220 H=ASC(D$(I,I))-48:L=ASC(D$(I+1,I+1))-48
230 D=(H-(H>9)*7)*16+L-(L>9)*7:S=S+D
240 IF FLAG=1 THEN 270
250 IF I=13 THEN D=ML
260 IF I=15 THEN D=MH:FLAG=1
270 PUT #1,D:NEXT I:IF S=P THEN 190
280 ? :? :? "DATENFEHLER IN ZEILE ";PEEK(183)+PEEK(184)*256:CLOSE #1:STOP
290 REM * FILE SCHLIESSEN
300 CLOSE #1
310 ? :? :? "AUTORUN.SYS ordnungsgemaess erzeugt!"
320 END
1100 DATA FFFF00062706004020FFFFAD00068DE702AD01068D,2041
1110 DATA E80260A50C8D0306A50D8D0406A902850CA906850D,1623
1120 DATA 4C050600FFFFE202E3021206,1078
1130 DATA *,0