*************************************
* Speicherplatz-Reservierung m. MEMLO
*
* Aufzeichnen: als AUTORUN.SYS
* von $600 bis $627
* und $2E2 bis $2E3 (mit Append!)
* Assembler: ATMAS-II
*************************************
*
DOSINI	EQU $0C		;DOS-Init nach RESET
MEMLO	EQU $2E7	;untere Speichergrenze
*
	ORG $600
*
LOWRAM 	DFW $4000 	;neues MEMLO (wird ersetzt)
*
* Einsprung nach RESET
* wird in die DOS-Initialisierung
* eingebunden
*
NEUINI	JSR $FFFF	;Platz fuer DOSINI
KALT	LDA LOWRAM	;neue MEMLO-Adresse
	STA MEMLO	;eintragen (waehrend
	LDA LOWRAM+1	;RESET!)
	STA MEMLO+1
	RTS		;das war's!
*
* Einbindung der Routine in den
* RESET-Ablauf
*
START	LDA DOSINI	;DOS-Init in leeren
	STA NEUINI+1	;JSR eintragen
	LDA DOSINI+1	;jetzt MSB
	STA NEUINI+2
	LDA #NEUINI:L	;neues DOSINI
	STA DOSINI	;eintragen
	LDA #NEUINI:H
	STA DOSINI +1
	JMP KALT	;MEMLO vorbesetzen
*
* File-Init Adresse fuer AUTORUN.SYS
*
	ORG $2E2
	DFW START
*
