**********************************
* START NACH RESET
*
* Beispiel fuer Maschinenprogramme
**********************************
*
BOOT	EQU 9		;2:Cass-Boot O.K.
CASINI	EQU $02		;Vektor Init. nach RESET
SDLSTL	EQU $230	;Zeiger auf D-List
VCOUNT	EQU $D40B	;Rasterzeile
COLBK	EQU $D01A	;Hintergrund
*
	ORG $0600
*
	LDA #2		Cass-Boot
	STA BOOT	vortaeuschen
	LDA #START:L	Start-Adresse
	STA CASINI	eintragen
	LDA #START:H
	STA CASINI+1
*
* Einsprung nach RESET
*
START	LDA #DLIST:L	Display-List
	STA SDLSTL	aktivieren
	LDA #DLIST:H	jetzt MSB
	STA SDLSTL+1
ENDLOS	LDA VCOUNT	und ein wenig
	STA COLBK	Farbe
	JMP ENDLOS
*
* einfache Displaylist
*
DLIST	DFB $70,$70,$70,$70,$70,$70
	DFB $70,$70,$70,$70,$70,$46
	DFB SCR:L,SCR:H,$41
	DFW DLIST
SCR 	ASC % PROGRAMM LAEUFT... %